Automator if/then conditional action possible?

Unfortunately Automator has no conditional logic control - even its Loop action is less use than a chocolate fireguard.

I would suggest writing an AppleScript to check the folder and send the mail, then save the script as an AppleScript application, and finally set up a scheduled alert in Calendar to open the script app file, which will then run. It should get the result you need without involving Automator at all.

I shall have a think about a script...

This AppleScript will check that the modification date of a specified folder, and send a message if it has not been modified in the last day:

set checkFolder to (path to documents folder from user domain as string) & "Manuals:"
tell application "System Events" to set folderChanged to modification date of folder checkFolder
set noUpdate to (current date) - folderChanged > 1 * days
if noUpdate then
	tell application "Mail"
		set theRecipient to "name@host.com" -- recipient's email address
		set recipientName to "name" -- recipient's name
		set theSubject to "File not created"
		set theBody to "The file you wanted has not been created"
		set alertMail to (make new outgoing message with properties {subject:theSubject, content:theBody})
		tell alertMail
			make new to recipient at end of to recipients with properties {address:theRecipient, name:recipientName}
		end tell
		send outgoing message 1
	end tell
end if

You'll need to set your own values for the variables theRecipient, recipientName, theSubject and theBody, and you'll need to set your own path for checkFolder. (For testing purposes I used a folder in my Documents folder called "Manuals" which was last modified more than a day ago.)

Copy and paste the script into a new Script Editor window, make your own modifications (post back if you need help defining the path), click the Hammer button in the toolbar to make sure it compiles, and you should get something like this:

Run it to check it works (you should get a true Result), then save as an Application, not stay-open, no splash screen, anywhere convenient.

Fire up Calendar, create a new daily recurring event, and set a Custom Alert for the event to open the application file.

This will run the script application every day. I think you'll have to be logged in to the Mac, though. TBH I'm not sure if the alert will run if you're not.

Cheers,

H

Sajik NZ wrote:

Do you mean the underlined part, if left verbatim and not replaced with actual file path, would still work?

Yes, on any machine. Although you've inadvertently removed a couple of the spaces - it should be:

path to applications folder from user domain

This is the relevant entry in the Standard Additions library:

So if you're monitoring the main Applications folder you could define it as

path to Applications folder from system domain

Your path construction:

":Applications:Profile for Mac:" etc etc

(beginning with a colon) appears to work fine when scripting System Events, but it wouldn't work if you wanted to script the Finder and many other applications: they require a full path including the name of the system drive, which may vary from machine to machine.

The "path to" construction gets round this. On my machine, if I run the single-line script

path to applications folder from system domain

I get the result

alias "Macintosh HD:Applications:"

If the hard drive was called Big Mac, the same script would result in

alias "Big Mac:Applications:"

It lets you write complex inter-application scripts without needing to know the name of the machine the script will run on, or the name of the user. In your situation it may not be necessary.

(An alias in this context is a reference to a system object, not a Finder alias file/"shortcut".)

Glad it worked 😃

Your live path will work, but only for you. If you need to make the script more portable, then:

set checkFolder to ((path to applications folder from user domain) as string) & "Profile Server Folder KG:Profile Data:Profile logs:Database Logs:"

would not have to be modified for every user. Your choice, though.