PAGES: Where did "share as pdf" go?

Apple removed the Share menu from Pages v12.2, and on Ventura, it appears that the Send a Copy that appears on my Pages v12.2 File menu on Monterey or earlier is also missing according to others using Ventura that have posted in this community.

The remedy on Ventura is to use the Pages File menu > Print… ( or cmd+p) > PDF > Send in Mail. This will open a Mail compose window with the PDF attached.

I have written an AppleScript that exports the Pages content to your interactive choice of Word, PDF, or RTF documents and then automagically opens a new Mail message with same document attached. It can be run with an open document in Pages, or run without Pages and it will pop a file chooser over the default Pages template chooser. You then select the Pages document, it gets exported and attached to new Mail per above.

I have tested this with Pages v12.2 on Ventura and have no reason to believe it would not work on Monterey too. It also works in a Shortcuts Run AppleScript and the Shortcuts allows you to save it to your Dock for one-click launch.

Here is the AppleScript that you can copy/paste into Dock > Launchpad > Other > Script Editor, then click the hammer icon on the Script Editor and then run the script to test it for yourself.

use scripting additions

property exportOptions : {"Word", "PDF", "RTF"}
property extDict : {msword:"docx", apdf:"pdf", rtf:"rtf"}

tell application "Pages"
	activate
	if not (exists front document) is true then
		set pages_doc to (choose file of type {"Pages"} default location (path to desktop)) as text
		set thisDoc to open pages_doc as alias
	else
		set thisDoc to front document
	end if
	
	set docPath to (thisDoc's file) as text
	set basename to text 1 thru ((offset of "pages" in docPath) - 1) of docPath
	
	set exportFormat to (choose from list exportOptions ¬
		with title "Export Options" default items {"Word"})
	
	if exportFormat is false then return
	
	with timeout of 1200 seconds
		if exportFormat contains "Word" then
			set expDoc to basename & msword of extDict
			export thisDoc to file expDoc as Microsoft Word
		else if exportFormat contains "PDF" then
			set expDoc to basename & apdf of extDict
			export thisDoc to file expDoc as PDF with properties {image quality:Best}
		else
			set expDoc to basename & rtf of extDict
			export thisDoc to file expDoc as formatted text
		end if
	end timeout
	close thisDoc saving no
end tell

tell application "Pages" to if it is running then quit

-- ensure exported file extension is visible in the Finder as by default it is not
tell application "Finder"
	try
		if exists (item expDoc as alias) then
			set extension hidden of (item expDoc as alias) to false
		end if
	end try
end tell

set theRecipients to {" "}
set theAttachment to (alias expDoc)
set theContent to "Test content" & return & return & "Attachment:" & return
log (theAttachment) as text

tell application "Mail"
	activate
	
	set theMessage to (make new outgoing message with properties {visible:true, subject:"File Attachment test", content:theContent & return & return})
	tell theMessage to (make new to recipient with properties {address:theRecipients})
	
	tell theMessage
		tell content to make new attachment with properties {file name:theAttachment} at after the last paragraph of it
	end tell
	delay 2
	# send theMessage
end tell

To build it as a macOS Shortcut app, you do the following:

1. Dock > Other > Shortcuts
2. Shortcuts > New

3. Enter run in the search field and choose Run AppleScript from the results.

4. Click in front of the on run {input, parameters} line and press return. Copy and paste the use scripting additions and two property statements before the on run {input, parameters} clause. Press return afterward to open up an empty line. Click the hammer icon. It will now look like this:

5. Select the single line that says (* Your script goes here *) and leave it selected. Then copy/paste the rest of the AppleScript source from the first tell statement to the end of the script onto that selection. Click the hammer icon to compile this Shortcuts Run AppleScript. Now the finished Shortcut will look like this, since I cannot expand the shortcut window to select as I did above and perform a screen shot. See my second post in this thread that avoids the 5000 character limit that blocked posting the full Shortcut code.

Part II.

What the finished Shortcut looks like:

use scripting additions

property exportOptions : {"Word", "PDF", "RTF"}
property extDict : {msword:"docx", apdf:"pdf", rtf:"rtf"}

on run {input, parameters}
	tell application "Pages"
		activate
		if not (exists front document) is true then
			set pages_doc to (choose file of type {"Pages"} default location (path to desktop)) as text
			set thisDoc to open pages_doc as alias
		else
			set thisDoc to front document
		end if
		
		set docPath to (thisDoc's file) as text
		set basename to text 1 thru ((offset of "pages" in docPath) - 1) of docPath
		
		set exportFormat to (choose from list exportOptions ¬
			with title "Export Options" default items {"Word"})
		
		if exportFormat is false then return
		
		with timeout of 1200 seconds
			if exportFormat contains "Word" then
				set expDoc to basename & msword of extDict
				export thisDoc to file expDoc as Microsoft Word
			else if exportFormat contains "PDF" then
				set expDoc to basename & apdf of extDict
				export thisDoc to file expDoc as PDF with properties {image quality:Best}
			else
				set expDoc to basename & rtf of extDict
				export thisDoc to file expDoc as formatted text
			end if
		end timeout
		close thisDoc saving no
	end tell
	
	tell application "Pages" to if it is running then quit
	
	-- ensure exported file extension is visible in the Finder as by default it is not
	tell application "Finder"
		try
			if exists (item expDoc as alias) then
				set extension hidden of (item expDoc as alias) to false
			end if
		end try
	end tell
	
	set theRecipients to {" "}
	set theAttachment to (alias expDoc)
	set theContent to "Test content" & return & return & "Attachment:" & return
	
	tell application "Mail"
		activate
		set theMessage to (make new outgoing message with properties {visible:true, subject:"File Attachment test", content:theContent & return & return})
		tell theMessage to (make new to recipient with properties {address:theRecipients})
		
		tell theMessage
			tell content to make new attachment with properties {file name:theAttachment} at after the last paragraph of it
		end tell
		delay 1
		# send theMessage
	end tell
	return input
end run

At this point, you can click the ▶︎ to run the Shortcut. I renamed mine (arbitrary name) from the Shortcuts menu, and then closed it to save it in my All Shortcuts category which will appear after the close. I recommend that you use a ">" character between Pages > Send a Copy, as it will get changed to Pages/Send a Copy due to the FInder.

You can now right-click on the Shortcut and choose Add to Dock for single-click access to it, or you can drag a copy of it over the Menu Bar menu item and access it from your Shortcuts menus extra location:

Open the Shortcuts Utility. Click on All Shortcuts and locate the Shortcut you created for Pages. Click and drag/drop that Shortcut onto the Menu Bar menu item in the left panel and it will be added to the Shortcuts menus extra icon. When you click that, you will see:

I just did this on Ventura 13.1, so know it works.

I've been so frustrated by this for the past few days!

I'm certainly aware of the command to mail as PDF in the print menu, but I used that share menu to send as a word document all the time; I even had a great keyboard shortcut set up for it, and that shortcut doesn't work anymore!

I wonder if Apple removed the whole menu for a specific reason...(previously it had options for pdf, word, epub, plain text, rtf, and pages template... even publish to apple books! well, that's the list still in iPad - see below) ... to encourage people to send their friends and colleagues pages documents instead of converting to word, etc.

I'm usually not a conspiracy theorist about these apple things but... this suck.

It seems like I can still do the old "trick" in pages (also keynote, numbers) on the ipad and iphone (I think) by just tapping little down facing arrow next to the name of the document at the top, then tapping export, then if i tap "word" I get a full share dialoge from iPadOS and I can choose mail or messages or whatever.

I thought we were done bringing features to iOS/iPadOS and not MacOS, but here I can't find that same feature in the Mac, and it used to exist in the share menu!

ugh!

Adam

still so frustrated with this! there's a share button but it doesn't let me export - and the share menu is gone! any solutions? can someone make an extension to use in the share button menu that comes up when clicking on it?

Indeed. One starts to think that people working at Apple think they work in an Apple only world. How can you have a meeting and suggest this let alone decide that this is a good idea? What about share as Word. Or from Numbers share as xlsx and so on and so on. It does my head in.

Brilliant. Really excellent work.

I have Monterey on another machine and the "send a copy" shortcut appears there with Pages 12.2.1. This leads me to wonder whether the issue is w Ventura, not Pages.

On my Monterey 12.6.1 iMac (Intel), Pages v12.2 provides a File menu Send a Copy menu item, or a Send a Copy toolbar item, both working as they did in earlier versions of Pages allowing one to pick (e.g. Mail) and choose a particular document type to attach. These are gone in the same version of Pages on Ventura 13.0.1 so it may be Pages, Ventura, or both causing the problem if not the deliberate act of the Pages product team. Time will tell.

There is no Pages v12.2.1 yet.

Sorry for the dumb comment and if I'm missing something obvious.

I've created the shortcut following your detailed instructions and now have the shortcut in my menu.

The question is how do I use it?

I've opened a pages doc and then clicked on the shortcut but nothing happens.

Am I missing something?

The shortcut, when configured per my instructions, with a single click, will work with a document already opened in Pages, or without Pages running at all. In the latter case, it will launch Pages which should present its template chooser, and after a couple of seconds, a File chooser window will open where you select the Pages document, and then respond to the list of formats. Pages then exports the document in that format and opens a new Mail compose window with that document attached.

The fact that your clicking on the Shortcut resulting in nothing happens suggests to me that something is not correct in the Shortcut. Are you on macOS Ventura 13.0.1?

Launch the Shortcuts application. Locate your Pages shortcut and right-click on it. Choose Edit. Compare what you have in your AppleScript code in that Shortcut to what I posted above for the Shortcuts AppleScript in the finished Shortcut. Anything obvious?

The part I script was tested on local documents and breaks if you are syncing Pages documents to iCloud Drive's Pages folder, and selecting your document from there in the Finder. There are some short fixes that I recommend applying to the AppleScript source above before pasting it into the Shortcut's AppleScript action. These will naturally change what I have posted in Part II for the Shortcut code content:

Change:

property extDict : {msword:"docx", apdf:"pdf", rtf:"rtf"}

to:

property extDict : {msword:".docx", apdf:".pdf", rtf:".rtf"}

Change:

set basename to text 1 thru ((offset of "pages" in docPath) - 1) of docPath

to:

set basename to text 1 thru ((offset of ".pages" in docPath) - 1) of docPath

Click the hammer icon on the Script Editor to compile these changes. Then go on to part II where you copy/paste this code into the Shortcut Run AppleScript action as directed there.

Thanks VikingOSX, the shortcut works really well.

I'm still disappointed that Apple did not correct the Share menu shortcomings in yesterday's update.

I don't have any AppleScript skills and wondered if I could be a bit cheeky.

Your script covers the main half of what I have used the share menu for. I also archive pdf copies of my documents to DEVONthink (DT). It's possible to do this via the print menu but that option strips out any tags which I have applied (I use these extensively to manage my documents). Is it possible to adapt this script to export the document as a .pdf & send it to the DT inbox?

The Shortcut code asks you if you want to export to PDF and if selected, it does that to the original location of the Pages document. With the PDF on disk, you can move it into DevonThink, as I don't have that application here to develop or test against.

This is really so annoying! Could you please Apple fix this in a next update? that's what I loved about sharing, now it's really so annoying. I can't believe we have to install a script to fix something that was so easy and used to work, just because Apple took it away!

Please!!!