Shortcuts App for Mac

Apple's Script Editor is for AppleScript and JavaScript, but not other scripting languages. If you want to develop shell scripts, then the free BBEdit would be a good start. After its initial trial is over, it defaults to a free text editor.

Replace the entire code in the Run Shell Script with the following:

#!/bin/zsh

: <<"COMMENT"
Script that takes two folders from the command line and compares the files in the first
folder to those in the second folder. It performs an array difference to isolate
files unique to the first folder.

Usage: ${ZSH_ARG0} folder1 folder2

COMMENT

typeset -a firstdir=() otherdir=() diffdir=()

SRCDIR="${1:a:s/\~\//}"
NXTDIR="${2:a:s/\~\//}"

# just put the filename without path or extension (:r:t) in the array
# sort the case-insensitive filenames alphabetically (on)
setopt nocaseglob
firstdir=( ${SRCDIR}/*.psd(.Non:r:t) )
otherdir=( ${NXTDIR}/*.(jpg|jpeg|jp2)(.Non:r:t) )

# array difference comparison
diffdir=( ${firstdir:|otherdir} )
# print out the tilde path to each file in diffdir
for f in ${diffdir};
do
	print -Dl "${SRCDIR}/${f:t}.psd"
done
unset firstdir otherdir diffdir
exit 0

I have stripped the path and file extension of the sorted elements placed in the respective arrays. Additionally, I have allowed for different extensions for jpeg categories. Assumptions here are the first passed folder is .psd files and the second folder is jpegs. Similarly, I have added the .psd extension to the differences files for the text report.

You could wipe the contents of that Run Shell Script and then copy/paste the script code above and paste right back into the Run Shell Script.

The following code in a Zsh script, when passed the first folder and second folder (in that order) will list the files in the first folder that are not found in the second folder. Tested on macOS 13.3.1 with Zsh 5.9.

#!/bin/zsh

# arrays
typeset -a firstdir=() otherdir=() diffdir=()

# in case tilde paths passed in the Terminal need smacked into absolute (:a) paths
SRCDIR="${1:a:s/\~\//}"
NXTDIR="${2:a:s/\~\//}"

# just put the sorted (on) filename.ext in the arrays using :t
firstdir=( ${SRCDIR}/*(.Non:t) )
otherdir=( ${NXTDIR}/*(.Non:t) )
# array difference comparison, use the * operator for intersections of common elements
diffdir=( ${firstdir:|otherdir} )
# print out the tilde path to each file in diffdir
print -Dl ${${diffdir}:a}
unset firstdir otherdir diffdir
exit 0

If have two folders on my Desktop and the first selected folder has two files not present in the second folder. This script lists those two files from the first folder — when run as a Zsh script, or interactively input in the Terminal.

The same code doesn't display an error but is ignored in a Shortcuts Run Shell Script even when one can confirm that the selected folders are passed in by selection order. This wouldn't happen in an Automator Run Shell Script.

Shortcuts is Apple's strategic direction away from Automator, but for some solutions, it costs considerable time to get a working shortcut that should take five minutes to implement in Automator.

A slight correction. To output the correct tilde path from the first folder, one needs this code that incorporates the path to the first folder:

#!/bin/zsh

: <<"COMMENT"
Script that takes two folders from the command line and compares the files in the first
folder to those in the second folder. It performs an array difference to isolate
files unique to the first folder.

Usage: ${ZSH_ARG0} folder1 folder2

COMMENT

typeset -a firstdir=() otherdir=() diffdir=()

SRCDIR="${1:a:s/\~\//}"
NXTDIR="${2:a:s/\~\//}"

# just put the sorted (on) filename.ext in the arrays using :t
firstdir=( ${SRCDIR}/*(.Non:t) )
otherdir=( ${NXTDIR}/*(.Non:t) )
# array difference comparison
diffdir=( ${firstdir:|otherdir} )
# print out the tilde path to each file in diffdir
for f in ${diffdir};
do
	print -Dl "${SRCDIR}/${f:t}"
done
unset firstdir otherdir diffdir
exit 0

which would output:

and without a script, but in the Terminal, one can use the UNIX diff utility to show a difference:

The following Automator application will write a text file on your Desktop containing the file paths that are only in your first directory selection. I used two Ask for Finder Items in case the directories that you select are not located in the same location. If they are, you can remove one of the Ask Finder Items, select Allow Multiple Section, and use the ⌘-key to select multiple folders in the one action. I am not processing sub-folders in these selected folders for simplicity and not introducing potential duplicates, although that can be managed if you need it.

Here is the workflow:

and the contents of the text file written to the Desktop where the tilde character replaces /Users/yourname in the filepath.

~/Desktop/A/text0017.txt

~/Desktop/A/text0018.txt