Specific Default Alert Times for specific calendars

The default alert times are the same for all calendars.

You can however completely disable the alerts for a whole calendar. Tap on Calendars at the bottom of the screen, then on the circled i on its right in the list, and on the next screen you'll find a toggle for the notifications.

You can do it with a script.

See these instructions to install the script in the menu bar. It describes Numbers but is adaptable to Calendar.

Open this in Script Editor and adapt it to your needs if you are a bit familiar with AppleScript.

-- This script reads the events of a selected calendar and set new alarm times
-- It could be made more sophisticated to request trigger intervals or dates at run time. This is a basic demo.
-- Recycleur, discussions.apple.com 255296861
-- 2023-11-27

tell application "Calendar"
	set listCalendars to {}
	repeat with aCalendar in calendars
		set end of listCalendars to aCalendar's name
	end repeat
	
	set theCalendar to choose from list listCalendars with title "Available calendars" with prompt ¬
		"Choose the calendar to which set the alarm times for all its events." & return & ¬
		"CAUTION: This action is irreversible." OK button name "Continue" cancel button name "Stop"
	
	if theCalendar is not false then
		tell calendar (item 1 of theCalendar)
			set countEvents to 0
			repeat with anEvent in events
				tell anEvent
					
					-- this will only cover events whose FIRST occurence is in the future.
					-- To change the alarms for repeated events that started in the past, remove this if and its end if
					if start date > (current date) then
						
						-- Two ways to set an alarm, by date or by interval. Adapt the script as required.
						set triggerDate to start date
						-- setting a fixed time is optional, the line could be commented out
						set {triggerDate's hours, triggerDate's minutes, triggerDate's seconds} to {7, 25, 0}
						
						if not (exists first display alarm) then make new display alarm
						set first display alarm's trigger date to (triggerDate - 2 * days)
						
						if not (exists second display alarm) then make new display alarm
						set second display alarm's trigger interval to -75 -- minutes
						
						--if not (exists third display alarm) then make new display alarm
						--set third display alarm's trigger interval to 0 -- minutes
						
						--if not (exists fourth display alarm) then make new display alarm
						--set fourth display alarm's trigger interval to -90 -- minutes
						
						--if not (exists fifth display alarm) then make new display alarm
						--set fifth display alarm's trigger interval to -300 -- minutes
						
						--if not (exists sixth display alarm) then make new display alarm
						--set sixth display alarm's trigger interval to -3000 -- minutes
						
						set countEvents to countEvents + 1
					end if
				end tell
			end repeat
		end tell
		display dialog "New alarm times set for " & countEvents & " events"
	else
		display dialog "No change to alarm times"
	end if
end tell