Can not copy files between Finder and Microsoft Remote desktop

Had some time to experiment, and came up with this AppleScript/Objective-C solution that will take the file:/// as shown on your clipboard, and copy it to your Downloads folder as the same filename (without the percent encoding. The caveat is that the location of the file as your example shows, may not let you access the Word document without elevated privileges, something this AppleScript does not provide.

Copy and paste into the Script Editor, click compile, and when you are certain you have a file on the clipboard as shown previously, then run the script. It does some error checking to ensure their is a file reference on the clipboard.

use framework "Foundation"
use scripting additions

property NSPasteboard : a reference to current application's NSPasteboard
property NSFileManager : a reference to current application's NSFileManager
property NSURL : a reference to current application's NSURL
property dialog_title : "Clipboard File Copy"

set pb to NSPasteboard's generalPasteboard()
set cliptxt to (pb's stringForType:(current application's NSPasteboardTypeString)) as text
if not cliptxt = missing value then
	log cliptxt as text
end if

if cliptxt does not start with "file:///" then
	display dialog "File URL format not on clipboard… quitting." with title dialog_title
	return
end if

set theFile to NSURL's URLWithString:cliptxt
set fileURLstatus to (theFile's absoluteURL)'s fileURL

if fileURLstatus then
	
	set fm to NSFileManager's defaultManager()
	set fname to theFile's lastPathComponent()
	set userhome to (fm's homeDirectoryForCurrentUser)'s URLByAppendingPathComponent:"Downloads"
	set destpath to userhome's URLByAppendingPathComponent:fname
	set status to fm's copyItemAtURL:theFile toURL:destpath |error|:(reference)
	if (item 1 of status) then -- true is successful file copy result
		display dialog "Written to destination: " & return & return & destpath with title dialog_title
	else
		display dialog "Failed to write/overwrite existing destination file: " & return & return & destpath with title dialog_title
	end if
else
	display dialog "No file on the clipboard" with title dialog_title
end if
return

Tested on Big Sur 11.1.

You should be using the current Microsoft Remote Desktop v10.5.0 in the Mac App Store, which is intended for Big Sur. Remote Desktop expects that you are connecting to Windows 10 Professional, Enterprise, or Server, and that the Windows side is configured correctly. Also, check your Remote Desktop Preferences for settings.

Two things that I observe are that 1) I don't believe that Finder knows how to copy file URL (with UNIX paths) to other Finder filesystem locations, and 2) does not know what to do with percent encoded paths (e.g. fra%20rdp.docx, which is fra rdp.docx).

Either Microsoft does not have support for copy/paste in RDC, conceals the capability in its Preferences, or has not thought out how Finder handles files. Perhaps it will support drag and drop from the Windows interface, directly to your Downloads folder.

For non-Norwegian speakers, your error dialog states:

The operation cannot be completed because one or more of the objects were not found. (Error code -43)

Hello Ppedersen85,

Welcome to the Apple Support Communities, and from your post it appears on the MacBook Air there are issues using a specific function in Microsoft's Remote Desktop app. We'll do what we can to help or point you to the right place.

According to Microsoft's website, the Mac currently doesn't have the option for the app, only iOS devices: How to use Remote Desktop

If you are running the iOS version using the new M1 feature, just remember that some features might not be able to be utilized while running under Mac. It'll be best to reach out to the developer of the app to be sure: Contact Us - Microsoft Support

Thanks and have a wonderful day.