Big Sur 11.1 (20C69) – Problems with finder navigation from ANY Application

The open and save panels from any application are not the Finder, but rather Apple AppKit framework (library) classes designed to look, and with restrictions, work like a Finder window. The Finder has nothing to do with them, and the application cannot remember your resizing them. This is either an intentional, or accidental design issue that can only be fixed by Apple in a future Big Sur update.

Here is some AppleScript/Objective-C code that presents an Open panel on the Desktop sized as it would be from a Mojave application (e.g. Preview). Click the Launchpad in the Dock, select the Other folder, and launch Script Editor. Copy/paste the following code into Script Editor, and then press control+command+R to launch the Open panel dialog. Whatever you select will be shown as a listing in the resulting display dialog.

AppleScript/Objective-C

-- Demonstration of a multiple-selection Open panel as it should appear in macOS 11.1
-- VikingOSX, 2020-12-22, Apple Support Communities, No warranty expressed or implied

use framework "AppKit"
use AppleScript version "2.4" -- Yosemite or later
use scripting additions

property NSThread : a reference to current application's NSThread
property NSString : a reference to current application's NSString
property NSURL : a reference to current application's NSURL
property NSOpenPanel : a reference to current application's NSOpenPanel

property default_location : "~/Desktop"
property HFS : "HFS"
property POSIX : "POSIX"

if not (current application's NSThread's isMainThread()) as boolean then
	display alert "This script must be run interactively from the main thread by pressing control+commmand+R keys." buttons {"Cancel"} as critical
	error number -128
end if

-- choice of HFS or POSIX path formatting on return of selection(s)
set openstuff to my open_panel(POSIX, default_location) as list

set {TID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, return}
display dialog (items of openstuff) as text with title "List of Selected Files and folders"
set AppleScript's text item delimiters to TID
return

on open_panel(afmt, this_location)
	
	if this_location starts with "~" then
		set this_location to ((NSString's stringWithString:this_location)'s stringByStandardizingPath()) as text
	else
		-- trim trailing '/' from folder path to match stringByStandardizingPath result
		set this_location to text 1 thru -2 of (POSIX path of this_location)
	end if
	
	set location_URL to NSURL's fileURLWithPath:this_location
	
	set oPanel to NSOpenPanel's openPanel()
	
	tell oPanel
		its setFloatingPanel:true
		its setResolvesAliases:true
		its setAccessoryViewDisclosed:true
		its setCanDownloadUbiquitousContents:true -- for iCloud
		its setDirectoryURL:location_URL
		-- make open panel dialog the same size as on Mojave, in stark contrast with Big Sur 11.1
		-- comment the next line to show panel without normal sizing
		its setFrame:(current application's NSMakeRect(0, 0, 830, 580)) display:true
		its setTitle:"Sample Open Panel"
		its setMessage:"Select additional file(s) and folder(s) with ⌘-key"
		its setPrompt:"Select"
		its setAllowsMultipleSelection:true
		its setCanChooseFiles:true
		its setCanChooseDirectories:true
		its setTreatsFilePackagesAsDirectories:false
	end tell
	
	set returnCode to oPanel's runModal()
	if returnCode is (current application's NSFileHandlingPanelCancelButton) then
		error number -128 -- user pressed cancel button
	end if
	
	if afmt is "HFS" then
		return (oPanel's URLs) as list
	else if afmt is "POSIX" then
		return (oPanel's filenames()) as list
	else
		error number -128 -- can't have both
	end if
	return
	
end open_panel

I'm thinking that your finder preferences got corrupted.