Hyperlinks in Apple Numbers

This is a user-to-user forum. You might consider giving your comments to Apple via Numbers > Provide Numbers Feedback in the menu.

SG

Send your feature request to Apple.

Numbers->Provide Numbers Feedback

If you would be okay with clicking a cell (one that has a sheet name in it) then using a keyboard shortcut to make the actual jump, a script is available that can do that. It can jump you to a specific sheet:table::cell or to sheet:table::A1 if the cell is not provided. The script can be saved as a service or shortcut and assigned a keyboard shortcut. A column of sheet names in a table can be created automatically with some formulas if there is a pattern to the sheet names (Sheet 1 Sheet 2 etc or Jan Feb Mar etc.) that can be created by formula.

-- Goto Numbers Cell
-- In a cell in a table will be text of the form sheetname::tablename::cellname
-- such as Sheet 1::Table 1::D4
-- Select the cell then run the script and the focus should move to the specified cell.
-- Alternatively, the cell may contain sheet and table name without the cell name
-- such as Sheet 1::Table 1
-- In this case the focus will move to cell A1 of the specified table



tell application "Numbers"
	tell front document
		tell active sheet
			tell (first table whose selection range's class is range)
				set linktext to (value of first cell of (selection range)'s cells as text)
			end tell
		end tell
		
		set myArray to my theSplit(linktext, "::")
		
		set active sheet to sheet (item 1 of myArray)
		tell active sheet to tell table (item 2 of myArray)
			if number of items of myArray = 3 then
				set selection range to cell (item 3 of myArray)
			else
				set selection range to cell "A1"
			end if
		end tell
		
	end tell
end tell


on theSplit(theString, theDelimiter)
	-- save delimiters to restore old settings
	set oldDelimiters to AppleScript's text item delimiters
	-- set delimiters to delimiter to be used
	set AppleScript's text item delimiters to theDelimiter
	-- create the array
	set theArray to every text item of theString
	-- restore the old setting
	set AppleScript's text item delimiters to oldDelimiters
	-- return the result
	return theArray
end theSplit