Simple Automator Folder Action Not Working

If those are the only two actions in the workflow, my guess would be that the filter action is not finding anything - note that it uses Spotlight, so if the items are not indexed (yet) there may not be any results. Another way to troubleshoot would be to add something like a Copy to Clipboard action after the filter action to see what its results are.

Remove the "Show this action when the workflow runs" option if you don't want it to.

You could start by posting the screen shot of your workflow, rather than subject us to guesswork as to why it isn't working. Even if it isn't working correctly it will show the spinning gear in the menu bar.

Ah - you placed the script into a Run AppleScript Automator action. The script as originally posted was stand-alone did not need Automator at all. Placing it into the ~/Library/Scripts/Folder Action Scripts folder was all that was necessary to have it show up in the Folder Action Setup service, with the extra benefit of it being able to be run in the Script Editor for testing.

Normally there isn't any indication that a folder action is running (including errors) - are you saying that you are seeing results copied to the clipboard? Are you testing by moving existing files or downloading new ones?

The only thing I can think of is that the file gets indexed when showing the dialog; Automator is just goofy that way. You can use the following script instead - it doesn't use Spotlight and can be run as an application, from the Script Editor, or as a folder action (for the latter, place the script in your user's ~/Library/Scripts/Folder Action Scripts folder):

# application double-clicked or run from the Script Editor
on run
  doStuff for (choose file with multiple selections allowed)
end run

# file items dropped onto the application
on open theFiles
  doStuff for theFiles
end open

# process a list of file items
to doStuff for someFiles
  repeat with anItem in someFiles
    set anItem to anItem as text
    tell application "System Events" to set {theClass, theName} to {class, name} of disk item anItem
    if (theClass as text) is not in {"folder", "«class cfol»"} then -- a file or bundle
      tell application "System Events"
        set extension to name extension of disk item anItem
        if extension contains "added" then move disk item anItem to (path to desktop)
      end tell
    end if
  end repeat
end doStuff

# handle file items added to a folder
on adding folder items to this_folder after receiving these_items
  doStuff for these_items
end adding folder items to

You don't have to change the run handler, it is just there so that your task can also be run from the Script Editor (or as an application) - the on adding folder items to this_folder after receiving these_items handler is what is called by the system when you attach it to a folder as a folder action.